Fast multiple search and replace in Perl

Question

I have a file: map.txt - which is having 1000+ lines like below format:

aaa { 123 };
bbb { 4567 };
cc { 89 };

I have another file input.txt having 5 Million+ lines;
which contains aaa as "aaa", bbb as "bbb" format.

Can I get a suggestion for a fastest method in perl to search & replace all occurrence of:
"aaa" with "123"
"bbb" with "4567" so on.

Answer 1

Use a hash. Use the old strings as keys, replacement strings as values.

#!/usr/bin/perl
use warnings;
use strict;

my %map;
open my $MAP, '<', 'map.txt' or die $!;
while (<$MAP>) {
    my ($pattern, $replacement) = /(.*) { (.*) };/;
    $map{$pattern} = $replacement;
}

open my $IN, '<', 'input.txt' or die $!;
while (<$IN>) {
    s/"(.*)"/"$map{$1}"/g;
    print;
}

To output to a new file, change the last paragraph as follows:

open my $IN,  '<', 'input.txt' or die $!;
open my $OUT, '>', 'output.txt' or die $!;
while (<$IN>) {
        s/"(.*?)"/exists $map{$1} ? qq{"$map{$1}"} : qq{"$1"}/ge;
    print {$OUT} $_;
}
close $OUT;