sql - Raise statement

Question

Does statement RAISE rollback implicitly (in block EXCEPTION)?

thanks in advance

Answer 1

No. The block as a whole will get rolled back on failure, but the raise statement on its own does not perform a rollback.

For example, this block fails and is implicitly rolled back (exactly as if it was an SQL insert etc):

begin
    insert into demo(id) values(1);
    dbms_output.put_line(sql%rowcount || ' row inserted');
    raise program_error;
exception
    when program_error then raise;
end;

ERROR at line 1:
ORA-06501: PL/SQL: program error
ORA-06512: at line 6

SQL> select * from demo;

no rows selected

But this block is not rolled back, even though there is a raise inside it:

begin
    begin
        insert into demo(id) values(1);
        dbms_output.put_line(sql%rowcount || ' row inserted');
        raise program_error;
    exception
        when program_error then
            dbms_output.put_line('Raising exception');
            raise;
    end;
exception
    when program_error then null;
end;

1 row inserted
Raising exception

PL/SQL procedure successfully completed.

SQL> select * from demo;

        ID
----------
         1

1 row selected.